TÆL.FLERE.HVIS funktion

Indhold

# TÆL.FLERE.HVIS

Returnerer antallet af celler, der opfylder kriterierne i flere intervaller.

Denne funktion er tilgængelig siden LibreOffice 4.0.

### Syntaks

TÆL.FLERE.HVIS (Område; Kriterie[; Område2; Kriterie2][; ... ; [Område127;Kriterie127]])

Område 1 – obligatorisk argument. Det er et celleområde, et navn på et navngivet område eller en kolonne- eller række-overskrift, som det tilsvarende kriterie skal anvendes på.

Kriterium1: Et kriterium er et tekstudtryk beregnet fra en enkelt cellereference, en formel, et tal eller en tekst. Det bruges i sammenligninger med celleindhold.

En henvisning til en tom celle fortolkes som den numeriske værdi 0.

Et matchende udtryk kan være:

- Et tal eller en logisk værdi. Et overensstemmende celleindhold er lig med tallet eller den logiske værdi.

- En værdi, som begynder med en sammenligning (<, <=, =, >, >=, <>).

  For = passer en tom værdi med en tom celle.

  For <> passer en tom værdi med en ikke-tom celle.

  For <> passer en ikke-tom værdi med ethvert andet celleindhold end værdien, inklusive tomme celler.

  Bemærk: "=0" matcher ikke tomme celle.

  For = and <> gælder, at hvis værdien ikke er tom og ikke kan fortolkes som en talværdi eller undertype af tal, og hvis egenskaben Søgekriterier = og <> skal gælde for hele celler er krydset af, så sker sammenligningen med hele celleindholdet. Hvis feltet ikke er afkrydset, sker sammenligning med enhver underdel af feltet, som passer med kriterierne.

- Anden tekstværdi. Hvis egenskaben Søgekriterier = og <> skal gælde for hele celler er sand, sker sammenligningen med med hele cellens indhold, hvis falsk, sker sammenligningen med enhver underdel af feltet som passer til kriterierne. Udtrykket kan indeholde tekst, tal, regulære udtryk eller jokertegn (hvis jokertegn i formler er slået til i beregningsindstillinger).

Område2 – Valgfri. Område2 og alle de følgende betyder det samme som Område1.

Kriterie2 – Valgfri. Kriterie2 og alle de følgende har samme betydning som Kriterie.

Søgningen understøtter jokertegn eller regulære udtryk. Med regulære udtryk slået til, kan du for eksempel skrive "alle.*" for at finde den første placering af "alle" efterfulgt af vilkårlige tegn. Hvis du ønsker at søge efter en tekst som også er et regulært udtryk, så må du enten skrive tegnet "\" (backslash) før hvert enkelt metategn eller operator fra regulære udtryk, eller du må omkranse teksten med \Q...\E. Du kan slå automatisk evaluering af jokertegn eller regulære udtryk til og fra i LibreOffice ▸ IndstillingerFunktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til et sprog, hvor decimaltegnet ikke er punktum, vil konverteringen fungere. For at gennemtvinge evalueringen af det regulære udtryk frem for et numerisk udtryk, bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

Område, Område2, ... og Kriterie, Kriterie2, ... skal have samme størrelse, ellers returnerer funktionen fejl:502 – Ugyldigt argument.

Den logiske relation mellem kriterier kan defineres som logisk OG (Konjunktion). Med andre ord, hvis og kun hvis alle givne kriterier opfyldes, vil en værdi fra den korresponderende celle af det givne Funktions_område blive taget med i udregningen.

Funktionen kan have op til 255 argumenter, hviket betyder at du kan give 127 kriterieområder og kriterier for dem.

Hvis en celle indeholder SAND, betragtes det som 1, og hvis en celle indeholder FALSK betragtes det som 0 (nul).

### Eksempler

Betragt den følgende tabel

| A | B | C
1 | Produktnavn | Sales | Revenue
2 | pensel | 20 | 65
3 | kuglepen | 35 | 85
4 | notesblok | 20 | 190
5 | bog | 17 | 180
6 | pennalhus | ikke | ikke

I alle eksempler herunder, indeholder området for beregning af summen række #6, men den ignoreres, fordi den indeholder tekst.

#### Simpel brug

=TÆL.FLERE.HVIS(B2:B6;">=20")

Tæller antallet af rækker i området B2:B6 med værdier større end eller lig med 20. Returner 3, fordi den femte og sjette række ikke opfylder kriteriet.

=TÆL.FLERE.HVIS(B2:B6;">=20";C2:C6;">70")

Tæller mængden af rækker, der samtidigt indeholder værdier større end 70 i C2: C6 område og værdier større end eller lig med 20 i B2: B6 område. Returnerer 2, fordi den anden, den femte og sjette række ikke opfylder mindst ét kriterium.

#### Bruger regulære udtryk og indlejrede funktioner

For at disse eksempler kan fungere som beskrevet sikrer du dig, Aktiver regulære udtryk i formler er markeret i LibreOffice ▸ IndstillingerFunktioner ▸ Options ▸ LibreOffice Calc ▸ Beregn.

=TÆL.FLERE.HVIS(B2:B6;"[:alpha:]*")

Tæller antallet af rækker i området B2:B6 som alene indeholder alfabetiske tegn. Returnerer 1, fordi kun sjette række opfylder kriteriet.

=TÆL.FLERE.HVIS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Tæller antallet af rækker i området B2:B6, undtaget rækker med minimums- og maksimumsværdier i dette område. Returnerer 2, fordi tredje og sjette række ikke opfylder mindst et af kriterierne.

=TÆL.FLERE.HVIS(A2:A6;"pen.*";B2:B6;"<"&MAKS(B2:B6))

Tæller antallet af rækker der svarer til alle celler i området A2:A6 som begynder med "pen" og til alle celler i området B2:B6 med undtagelse af dettes maksimum. Returnerer 1, fordi kun anden række opfylder alle kriterier.

#### Reference til en celle som kriterium

Hvis du har brug for nemt at kunne ændre et kriterium, kn du med fordel angive dette i en celle og benytte en reference til denne celle i betingelsen for TÆL.HVIS funktionen. For eksempel, ovenstående funktion kan omskrives til følgende:

=TÆL.FLERE.HVIS(A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Hvis E2 = pen, returnerer funktionen 1, fordi kæden til cellen erstattes med dennes indhold hvilket svarer til funktionen ovenfor.

#### Tekniske oplysninger

Denne funktion er en del af Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

Relaterede emner

Wiki-side for funktionen TÆL.FLERE.HVIS (på engelsk: COUNTIFS).

TÆL (på engelsk: COUNT), TÆL.HVIS (på engelsk: COUNTIF), ANTAL.BLANKE (på engelsk: COUNTBLANK), TÆLV (på engelsk: COUNTA)

TÆL.FLERE.HVIS, MINHVISER, MAKSHVISER, Funktionen MIDDEL.FLERE.HVIS (på engelsk: AVERAGEIFS, SUM.FLERE.HVIS (på engelsk: SUMIFS)

Liste over regulære udtryk

Støt os venligst!