exciter
Prev | Orchestra Opcodes and Operators | Next

## exciter

exciter — A non-linear filter system to excite the signal.

## Description

Plugin opcode in exciter.

"Filtered distortion to add brilliance to a signal"

## Syntax

    ares exciter asig, kfreq, kceil, kharmonics, kblend

## Initialization

## Performance

asig -- input signal

kfreq -- the lower end of the harmonics created.

kceil -- the upper end of the harmonics created.

kharmonics -- amount of harmonics in the range 0.1 - 10.

kblend -- blend between 2nd and 3rd order harmonics in the range -10 - +10.

exciter is a reimplementation of the calf exciter plugin.

## Examples

Here is an example of the exciter opcode. It uses the file exciter.csd.

Example 274. Example of the exciter opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;real-time audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o exciter.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr=44100
    ksmps=32
    nchnls=2
    0dbfs =1

    instr 1 ; excited sound + original sound

    a1 diskin2 "fox.wav", 1
    a2 exciter a1, 3000, 20000, 10, 10	;generate uneven harmonics at maximum setting
         outs a2+a1, a2+a1
    endin

    instr 2 ; original sound for comparison

    a1 diskin2 "fox.wav", 1
       outs a1, a1
    endin

    instr 3 ; the effect of the excited sound only

    a1 diskin2 "fox.wav", 1
    a2 exciter a1, 3000, 20000, 10, 10	;generate uneven harmonics at maximum setting
       outs a2, a2
    endin

    </CsInstruments>
    <CsScore>
    i1 0 3
    i2 3 3
    i3 6 3
    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: John ffitch after Markus Schmidt
August 2014

New in Csound version 6.04

Prev | Up | Next
event_i | Home | exitnow